BLOBエリアにPDFを読み込んで表示させたい

来年1月から電帳法が始まりすが、電子帳票の保存をPDFでファイリングして、日付、取引先、金額の３つで検索が必要となります。
そこでPDFの読込をBLOB型フィールドを用意し、DOCUMENT TO　BLOBで読み込む方法を教えてもらい、以下にしたのですがうまく表示されません。
$vhDocRef:=Open document("")
If (OK=1)
CLOSE DOCUMENT($vhDocRef)
DOCUMENT TO BLOB(Document; [電帳]書類) // Load the document
If (OK=0)
// Handle error
End if
End if

[電帳]書類)はBLOBフィールドです。

ご指導よろしくお願いします。

上記BLOBに取り込んだものを
ファイルに書き出した後、OPEN URLにそのパスをわたすことにより適切なアプリケーションに表示できるようですが、
ここのところがよくわかりません。

まず，ドキュメントの内容（[電帳]書類）だけでなく，ファイル名もテキストフィールドなどに保存しておくことをお勧めします。
フルパスからPath to objectまたはFileでファイル名を取り出すことができます。

ちなみにOpen documentとRead Modeでファイルを選択するのはv2003のやり方で，Select documentを使えばDOCUMENTシステム変数にフルパス，コマンドの戻り値にファイル名が返されて便利です。

仮に[電帳]ファイル名がファイル名だとして

Code:

$folder:=Folder(Temporary folder; fk platform path).folder(Generate UUID)
$folder.create()
$file:=$folder.file([電帳]ファイル名)
$file.setContent([電帳]書類)
OPEN URL($file.platformPath)

おなじことをクラシックな書き方で

Code:

$path:=Temporary folder+Generate UUID+Folder separator
CREATE FOLDER($path; *)
$path:=$path+[電帳]ファイル名
BLOB TO DOCUMENT($path; [電帳]書類)
OPEN URL($path)